mirror of
https://github.com/arthur-pbty/arthur-os.git
synced 2026-08-05 20:28:25 +02:00
Ryan Hughes
648bc54db1
Themes now drive typography the same way they drive colors: one [font] base-size in shell.toml is the rem root, and every Style.font.<token> (caption, bodySmall, body, subtitle, title, heading, display, displayLarge, iconSmall, icon, iconLarge) derives from it via a fixed multiplier. Themes can also pin individual tokens for stylistic emphasis. base-size is clamped 11..13 until row-height tokens exist. Bar dimensions move to the same singleton: [bar] size-horizontal / size-vertical replace the hardcoded 26/28 in Bar.qml, exposed as Style.bar.sizeHorizontal / sizeVertical. Style.qml also resolves the fontconfig 'monospace' alias via fc-match and exposes Style.font.resolvedFamily so panels can display the concrete family. Watches ~/.config/fontconfig/fonts.conf so it tracks 'omarchy font set <name>'. The qs.Ui kit (PillButton, Dropdown, Toggle, TextField, etc.) and every first-party plugin (bar widgets, settings, menu, clipboard, emoji, polkit, notifications, osd, image-picker, dev-gallery) now bind to Style.font.* instead of pixel literals. Only three deliberate display-scale outliers remain: the notification empty-state glyph and the weather flyout's hero temperature pair, all commented. Background plugin's applyTheme IPC fast-path also pushes shell.toml to Style so theme swaps update typography and bar size without waiting for inotify debounce. Dev gallery (omarchy dev ui-preview) now ships a Typography section that renders the full scale and theme tokens live, and its summon command is fixed (omarchy-shell-ipc -> omarchy-shell).
103 lines
3.1 KiB
QML
103 lines
3.1 KiB
QML
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
import qs.Commons
|
|
|
|
Item {
|
|
id: root
|
|
|
|
property QtObject bar: null
|
|
property string moduleName: "lockKeys"
|
|
property var settings: ({})
|
|
|
|
property bool capsOn: false
|
|
property bool numOn: false
|
|
property bool scrollOn: false
|
|
property bool hideWhenOff: true
|
|
|
|
function setting(name, fallback) {
|
|
var value = settings ? settings[name] : undefined
|
|
return value === undefined || value === null ? fallback : value
|
|
}
|
|
|
|
Component.onCompleted: {
|
|
hideWhenOff = setting("hideWhenOff", true) === true
|
|
refresh()
|
|
}
|
|
|
|
function refresh() {
|
|
if (!stateProc.running) stateProc.running = true
|
|
}
|
|
|
|
property bool ledsAvailable: true
|
|
|
|
Process {
|
|
id: stateProc
|
|
command: ["bash", "-lc", "read_led() { for path in /sys/class/leds/input*::$1; do if [[ -r $path/brightness ]]; then cat $path/brightness; return; fi; done; echo missing; }; read_led capslock; read_led numlock; read_led scrolllock"]
|
|
stdout: StdioCollector {
|
|
waitForEnd: true
|
|
onStreamFinished: {
|
|
var lines = String(text || "").split("\n")
|
|
var caps = String(lines[0] || "").trim()
|
|
var num = String(lines[1] || "").trim()
|
|
var scroll = String(lines[2] || "").trim()
|
|
root.capsOn = caps !== "missing" && parseInt(caps, 10) > 0
|
|
root.numOn = num !== "missing" && parseInt(num, 10) > 0
|
|
root.scrollOn = scroll !== "missing" && parseInt(scroll, 10) > 0
|
|
root.ledsAvailable = caps !== "missing" || num !== "missing" || scroll !== "missing"
|
|
}
|
|
}
|
|
}
|
|
|
|
Timer {
|
|
interval: 2000
|
|
running: root.ledsAvailable
|
|
repeat: true
|
|
onTriggered: root.refresh()
|
|
}
|
|
|
|
readonly property bool anyOn: capsOn || numOn || scrollOn
|
|
visible: ledsAvailable && (hideWhenOff ? anyOn : true)
|
|
|
|
readonly property bool vertical: bar ? bar.vertical : false
|
|
|
|
implicitWidth: vertical ? (bar ? bar.barSize : 28) : (lay.item ? lay.item.implicitWidth + 8 : 0)
|
|
implicitHeight: vertical ? (lay.item ? lay.item.implicitHeight + 8 : 0) : (bar ? bar.barSize : 26)
|
|
|
|
Loader {
|
|
id: lay
|
|
anchors.centerIn: parent
|
|
sourceComponent: root.vertical ? colLayout : rowLayout
|
|
}
|
|
|
|
Component {
|
|
id: rowLayout
|
|
Row {
|
|
spacing: 4
|
|
LockGlyph { glyph: "A"; active: root.capsOn; visible: !root.hideWhenOff || root.capsOn }
|
|
LockGlyph { glyph: "1"; active: root.numOn; visible: !root.hideWhenOff || root.numOn }
|
|
LockGlyph { glyph: "S"; active: root.scrollOn; visible: !root.hideWhenOff || root.scrollOn }
|
|
}
|
|
}
|
|
|
|
Component {
|
|
id: colLayout
|
|
Column {
|
|
spacing: 2
|
|
LockGlyph { glyph: "A"; active: root.capsOn; visible: !root.hideWhenOff || root.capsOn }
|
|
LockGlyph { glyph: "1"; active: root.numOn; visible: !root.hideWhenOff || root.numOn }
|
|
LockGlyph { glyph: "S"; active: root.scrollOn; visible: !root.hideWhenOff || root.scrollOn }
|
|
}
|
|
}
|
|
|
|
component LockGlyph: Text {
|
|
property string glyph: ""
|
|
property bool active: false
|
|
|
|
text: glyph
|
|
color: active ? (root.bar ? root.bar.foreground : "#cacccc") : Qt.rgba(0.7, 0.7, 0.7, 0.3)
|
|
font.family: root.bar ? root.bar.fontFamily : "JetBrainsMono Nerd Font"
|
|
font.pixelSize: Style.font.bodySmall
|
|
}
|
|
}
|